blob: 673527a3a4b483916b371f0926a91c6ecbc7479c (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
|
CONFIG += ordered
TEMPLATE = subdirs
SUBDIRS += \
corelib \
views \
settings \
extensions \
translations
macx:SUBDIRS -= settings extensions
include(../mkspecs/common.pri)
contains(DEFINES, HAVE_ICU) {
SUBDIRS += icu-extradata
}
contains(DEFINES, HAVE_GCONF) {
# install gconf schema
unix {
schemas.CONFIG += no_check_exist
schemas.files = $${IN_PWD}/data/meegotouch.schemas
schemas.path = $${M_SYSCONFDIR}/gconf/schemas
schemas.commands = GCONF_CONFIG_SOURCE=$(GCONF_SCHEMA_CONFIG_SOURCE) gconftool-2 --makefile-install-rule $${IN_PWD}/data/meegotouch.schemas
INSTALLS += schemas
}
}
#install device configuration file
devices.CONFIG += no_check_exist
devices.files = $${IN_PWD}/data/targets/*.conf
devices.path = $${M_TARGETS_CONF_DIR}
INSTALLS += devices
themedaemonpriorities.CONFIG += no_check_exist
themedaemonpriorities.files = $${IN_PWD}/data/themedaemonpriorities.conf
themedaemonpriorities.path = $$M_INSTALL_SYSCONF/meegotouch
INSTALLS += themedaemonpriorities
# install MeeGo Touch feature files
install_prf.path = $$[QT_INSTALL_DATA]/mkspecs/features
install_prf.files = \
$${M_SOURCE_TREE}/mkspecs/features/meegotouch_common.prf \
$${M_BUILD_TREE}/mkspecs/features/meegotouch_defines.prf \
$${M_SOURCE_TREE}/mkspecs/features/meegotouch_translations.prf \
$${M_SOURCE_TREE}/mkspecs/features/meegotouchcore.prf \
$${M_SOURCE_TREE}/mkspecs/features/meegotouchsettings.prf \
$${M_SOURCE_TREE}/mkspecs/features/meegotouch.prf \
$${M_SOURCE_TREE}/mkspecs/features/meegotouch_mgen.prf \
$${M_SOURCE_TREE}/mkspecs/features/meegotouch_mmoc.prf \
$${M_SOURCE_TREE}/mkspecs/features/meegotouch-boostable.prf \
# causes problems when installing on windows with INSTALL_ROOT
!win32 {
INSTALLS += install_prf
}
# install Rich Text Editor xml file
install_xmltoolbar.files = data/RichTextEditorToolbar1.xml data/UrlContentToolbar.xml data/EmailContentToolbar.xml
install_xmltoolbar.path = $$M_INSTALL_PREFIX/share/meegotouch/imtoolbars
INSTALLS += install_xmltoolbar
# install pkgconfig file
install_pkgconfig.path = $$M_INSTALL_LIBS/pkgconfig
install_pkgconfig.files = \
data/meegotouchcore.pc \
data/meegotouchsettings.pc \
data/meegotouch.pc \
data/meegotouch-boostable.pc
INSTALLS += install_pkgconfig
# install forwarding headers
win32 {
# for windows we can live with the broken pattern matching
FORWARDING_HEADERS = include/M*
} else {
# match only the camel case forwarding headers here
FORWARDING_HEADERS = $$system( find include/M* )
}
forwarding_headers.path = $$M_INSTALL_HEADERS
forwarding_headers.files = $$FORWARDING_HEADERS
INSTALLS += forwarding_headers
|
