Changes: split .prf and .pc files up for the different modules

RevBy: Armin Berres, Bjoern Schnabel
Details: before you could do in a qmake .pro file:

CONFIG += meegotouch

and that would then link against libmeegotouchcore,
libmeegotouchviews, libmeegotouchsettings and
libmeegotouchextensions. now

CONFIG += meegotouchcore # only links against ...core

CONFIG += meegotouchsettings # links against ...core and
                             # ...settings

CONFIG += meegotouch # links against ...core, ...settings
                     # and ...extensions

nothing links against ...views any more, because it is loaded
at runtime from now on.

I added meegotouchcore.pc and
meegotouchsettings.pc and removed -lmeegotouchviews from
meegotouch.pc.

With these changes it should be possible to link only against
the parts of meegotouch that an application needs.

4 files changed, 82 insertions, 52 deletions

diff --git a/mkspecs/features/meegotouch.prf b/mkspecs/features/meegotouch.prf
index 6714408f..a1327f41 100644
--- a/mkspecs/features/meegotouch.prf
+++ b/mkspecs/features/meegotouch.prf
@@ -1,59 +1,15 @@
-######################################################################
-# MFeature
-######################################################################
+include(meegotouch_common.prf)
 
-include(meegotouch_defines.prf)
 macx {
-    INCLUDEPATH += /Library/Frameworks/m.framework/Headers
     LIBS += \
-            -framework meegotouchcore \
-            -framework meegotouchviews
+        -framework meegotouchcore \
+        -framework meegotouchsettings \
+        -framework meegotouchextensions
 } else {
-
-    contains(TEMPLATE, app) {
-        DEFINES += M_APPLICATION_NAME=\\\"${QMAKE_TARGET}\\\"
-    } else {
-        contains(TEMPLATE, lib) {
-            DEFINES += M_LIBRARY_NAME=\\\"lib${QMAKE_TARGET}\\\"
-        } else {
-            # error(Unknown template)
-        }
-    }
-
     !contains(DEFINES, BUILD_M) {
-        M_INC_DIR = $$M_PREFIX/include/meegotouch
-        M_LIB_DIR = $$M_LIBDIR
-
-        GSTREAMER_INC = /usr/include/gstreamer-0.10 /usr/include/glib-2.0 /usr/lib/glib-2.0/include /usr/include/libxml2
-
-        INCLUDEPATH += $${M_INC_DIR} $${GSTREAMER_INC}
-        DEPENDPATH += $${M_INC_DIR}
-
-        unix: QMAKE_LFLAGS += $${QMAKE_RPATH}$${M_LIB_DIR}
-        LIBS += -L$${M_LIB_DIR} -lmeegotouchcore -lmeegotouchviews -lmeegotouchsettings -lmeegotouchextensions
-
-        QMAKE_MOC = $${M_MMOC_EXECUTABLE}
-
-        isEmpty(MGEN_OUTDIR) {
-            MGEN_OUTDIR = .
-        }
-
-        mgenerator_model.name = mgenerator model
-        mgenerator_model.input = MODEL_HEADERS
-        mgenerator_model.output = $$MGEN_OUTDIR/gen_${QMAKE_FILE_BASE}data.cpp
-        mgenerator_model.commands += mgen --model ${QMAKE_FILE_NAME} $$MGEN_OUTDIR
-        mgenerator_model.clean += $$MGEN_OUTDIR/gen_*
-        mgenerator_model.CONFIG = target_predeps no_link
-        mgenerator_model.variable_out = GENERATED_SOURCES
-        QMAKE_EXTRA_COMPILERS += mgenerator_model
-
-        mgenerator_style.name = mgenerator style
-        mgenerator_style.input = STYLE_HEADERS
-        mgenerator_style.output = $$MGEN_OUTDIR/gen_${QMAKE_FILE_BASE}data.cpp
-        mgenerator_style.commands += mgen --style ${QMAKE_FILE_NAME} $$MGEN_OUTDIR
-        mgenerator_style.clean += $$MGEN_OUTDIR/gen_*
-        mgenerator_style.CONFIG = target_predeps no_link
-        mgenerator_style.variable_out = GENERATED_SOURCES
-        QMAKE_EXTRA_COMPILERS += mgenerator_style
+        LIBS += \
+	    -lmeegotouchcore \
+	    -lmeegotouchsettings \
+	    -lmeegotouchextensions
     }
 }
diff --git a/mkspecs/features/meegotouch_common.prf b/mkspecs/features/meegotouch_common.prf
new file mode 100644
index 00000000..ea3946b9
--- /dev/null
+++ b/mkspecs/features/meegotouch_common.prf
@@ -0,0 +1,52 @@
+include(meegotouch_defines.prf)
+macx {
+    INCLUDEPATH += /Library/Frameworks/m.framework/Headers
+} else {
+
+    contains(TEMPLATE, app) {
+        DEFINES += M_APPLICATION_NAME=\\\"${QMAKE_TARGET}\\\"
+    } else {
+        contains(TEMPLATE, lib) {
+            DEFINES += M_LIBRARY_NAME=\\\"lib${QMAKE_TARGET}\\\"
+        } else {
+            # error(Unknown template)
+        }
+    }
+
+    !contains(DEFINES, BUILD_M) {
+        M_INC_DIR = $$M_PREFIX/include/meegotouch
+        M_LIB_DIR = $$M_LIBDIR
+
+        GSTREAMER_INC = /usr/include/gstreamer-0.10 /usr/include/glib-2.0 /usr/lib/glib-2.0/include /usr/include/libxml2
+
+        INCLUDEPATH += $${M_INC_DIR} $${GSTREAMER_INC}
+        DEPENDPATH += $${M_INC_DIR}
+
+        unix: QMAKE_LFLAGS += $${QMAKE_RPATH}$${M_LIB_DIR}
+        LIBS += -L$${M_LIB_DIR}
+
+        QMAKE_MOC = $${M_MMOC_EXECUTABLE}
+
+        isEmpty(MGEN_OUTDIR) {
+            MGEN_OUTDIR = .
+        }
+
+        mgenerator_model.name = mgenerator model
+        mgenerator_model.input = MODEL_HEADERS
+        mgenerator_model.output = $$MGEN_OUTDIR/gen_${QMAKE_FILE_BASE}data.cpp
+        mgenerator_model.commands += mgen --model ${QMAKE_FILE_NAME} $$MGEN_OUTDIR
+        mgenerator_model.clean += $$MGEN_OUTDIR/gen_*
+        mgenerator_model.CONFIG = target_predeps no_link
+        mgenerator_model.variable_out = GENERATED_SOURCES
+        QMAKE_EXTRA_COMPILERS += mgenerator_model
+
+        mgenerator_style.name = mgenerator style
+        mgenerator_style.input = STYLE_HEADERS
+        mgenerator_style.output = $$MGEN_OUTDIR/gen_${QMAKE_FILE_BASE}data.cpp
+        mgenerator_style.commands += mgen --style ${QMAKE_FILE_NAME} $$MGEN_OUTDIR
+        mgenerator_style.clean += $$MGEN_OUTDIR/gen_*
+        mgenerator_style.CONFIG = target_predeps no_link
+        mgenerator_style.variable_out = GENERATED_SOURCES
+        QMAKE_EXTRA_COMPILERS += mgenerator_style
+    }
+}
diff --git a/mkspecs/features/meegotouchcore.prf b/mkspecs/features/meegotouchcore.prf
new file mode 100644
index 00000000..ed958b36
--- /dev/null
+++ b/mkspecs/features/meegotouchcore.prf
@@ -0,0 +1,9 @@
+include(meegotouch_common.prf)
+
+macx {
+    LIBS += -framework meegotouchcore
+} else {
+    !contains(DEFINES, BUILD_M) {
+        LIBS += -lmeegotouchcore
+    }
+}
diff --git a/mkspecs/features/meegotouchsettings.prf b/mkspecs/features/meegotouchsettings.prf
new file mode 100644
index 00000000..1018e1a4
--- /dev/null
+++ b/mkspecs/features/meegotouchsettings.prf
@@ -0,0 +1,13 @@
+include(meegotouch_common.prf)
+
+macx {
+    LIBS += \
+        -framework meegotouchcore \
+        -framework meegotouchsettings \
+} else {
+    !contains(DEFINES, BUILD_M) {
+        LIBS += \
+	    -lmeegotouchcore \
+	    -lmeegotouchsettings \
+    }
+}