blob: 8bbad2b51f56eda9a4762f1f341a38ec7f4703bc (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
|
FILESEXTRAPATHS_prepend := "${THISDIR}/configs:"
LICENSE = "MIT"
LIC_FILES_CHKSUM = "file://${COMMON_LICENSE_DIR}/MIT;md5=0835ade698e0bcf8506ecda2f7b4f302"
# Always create vmdk and vdi images for the compatible targets
IMAGE_FSTYPES_append_intel-corei7-64 = " wic.vmdk wic.vdi"
inherit core-image distro_features_check extrausers
SRC_URI = "\
file://bt-6lowpan.network \
file://modules-6lowpan.conf \
file://sysctl-panic.conf \
file://path-sbin.sh \
file://sudoers \
"
# let's make sure we have a good image..
REQUIRED_DISTRO_FEATURES = "pam systemd"
fakeroot do_populate_rootfs_common_src () {
# Allow sudo group users to use sudo
install -m 0440 ${WORKDIR}/sudoers ${IMAGE_ROOTFS}${sysconfdir}/sudoers.d/lmp
# Configs that are specific to this image
install -m 0644 ${WORKDIR}/bt-6lowpan.network ${IMAGE_ROOTFS}${exec_prefix}/lib/systemd/network/60-bt-6lowpan.network
install -m 0644 ${WORKDIR}/modules-6lowpan.conf ${IMAGE_ROOTFS}${exec_prefix}/lib/modules-load.d/6lowpan.conf
install -m 0644 ${WORKDIR}/sysctl-panic.conf ${IMAGE_ROOTFS}${exec_prefix}/lib/sysctl.d/60-panic.conf
# Useful for development
install -d ${IMAGE_ROOTFS}${sysconfdir}/profile.d
install -m 0644 ${WORKDIR}/path-sbin.sh ${IMAGE_ROOTFS}${sysconfdir}/profile.d/path-sbin.sh
}
IMAGE_PREPROCESS_COMMAND += "do_populate_rootfs_common_src; "
addtask rootfs after do_unpack
python () {
# Ensure we run these usually noexec tasks
d.delVarFlag("do_fetch", "noexec")
d.delVarFlag("do_unpack", "noexec")
}
EXTRA_USERS_PARAMS = "\
useradd -P osf osf; \
usermod -a -G sudo,users,plugdev osf; \
"
|
